home *** CD-ROM | disk | FTP | other *** search
/ Compute! Gazette 1985 December / 1985-12.d64 / vbanner 1525 (.txt) < prev    next >
Commodore BASIC  |  2022-09-20  |  1KB  |  42 lines
  1. 100 poke56,28:poke55,0:clr
  2. 110 cc=0:print"[147][144]    banner printer    [146]":print"press a key:"
  3. 120 print"u[146]_for upper case and    graphics":print"l[146]_for upper/lower case"
  4. 130 print"c[146]_for custom character  set (character data   must be in place!)"
  5. 140 getch$:ifch$=""then140
  6. 150 ifch$="u"thench=32768:printchr$(142):goto190
  7. 160 ifch$="l"thench=32768+2048:printchr$(14):goto190
  8. 170 ifch$="c"thenfork=7424to7431:pokek,0:next:poke36869,255:ch=7168:goto190
  9. 180 goto140
  10. 190 print"[147]what character do you want to make up the   large letters":gosub490
  11. 200 pp$=mt$:print"[147]what is your message  ":gosub490:n$=mt$
  12. 210 print"how tall (1 to 9)";:inputts:ifts<1thents=1
  13. 220 print"how wide (1 to"ts"[157])";:inputws:ifws>tsorws<1thenws=1
  14. 230 open1,4
  15. 240 forl=1tolen(n$)
  16. 250 a$=mid$(n$,l,1):print"printing[146] "a$:ifa$=" "thengosub460:goto360
  17. 260 q=asc(a$):q=q+(q>63)*64+(q>191)*64+(q=255)*33
  18. 270 i=ch+q*8
  19. 280 forj=7to0step-1
  20. 290 fork=7to0step-1
  21. 300 b=peek(i+k)
  22. 310 ifband2^jthenfort=1tots:pr$=pr$+pp$:nextt:goto330
  23. 320 fort=1tots:pr$=pr$+" ":nextt
  24. 330 nextk
  25. 340 forx=1tows:print#1,chr$(15)spc((72-ts*8)/2)pr$chr$(8):nextx:pr$=""
  26. 350 nextj
  27. 360 nextl
  28. 370 print#1,chr$(8):close1
  29. 380 poke36879,26:ifpeek(36869)=255thencc=1:poke36869,240
  30. 390 print"[147]press a key:":print"x to exit program":print"r to reprint message"
  31. 400 print"n to enter new message"
  32. 410 gety$:ify$=""then410
  33. 420 ify$="x"thenopen1,4:print#1,chr$(15):close1:poke36879,27:print"[147]":end
  34. 430 ify$="r"thengosub470:print"[147]"n$:goto230
  35. 440 ify$="n"then110
  36. 450 goto410
  37. 460 forx=1to8*ws:print#1,chr$(8):next:return
  38. 470 ifcc=1thenpoke36869,255:cc=0
  39. 480 return
  40. 490 poke198,5:poke631,5:poke632,34:poke633,34:poke634,20:poke635,144
  41. 500 mt$="":inputmt$:return
  42.